File indexing completed on 2025-05-11 08:23:49
0001 #include "fpsp-namespace.h"
0002 //
0003 //
0004 // ssin.sa 3.3 7/29/91
0005 //
0006 // The entry point sSIN computes the sine of an input argument
0007 // sCOS computes the cosine, and sSINCOS computes both. The
0008 // corresponding entry points with a "d" computes the same
0009 // corresponding function values for denormalized inputs.
0010 //
0011 // Input: Double-extended number X in location pointed to
0012 // by address register a0.
0013 //
0014 // Output: The function value sin(X) or cos(X) returned in Fp0 if SIN or
0015 // COS is requested. Otherwise, for SINCOS, sin(X) is returned
0016 // in Fp0, and cos(X) is returned in Fp1.
0017 //
0018 // Modifies: Fp0 for SIN or COS; both Fp0 and Fp1 for SINCOS.
0019 //
0020 // Accuracy and Monotonicity: The returned result is within 1 ulp in
0021 // 64 significant bit, i.e. within 0.5001 ulp to 53 bits if the
0022 // result is subsequently rounded to double precision. The
0023 // result is provably monotonic in double precision.
0024 //
0025 // Speed: The programs sSIN and sCOS take approximately 150 cycles for
0026 // input argument X such that |X| < 15Pi, which is the the usual
0027 // situation. The speed for sSINCOS is approximately 190 cycles.
0028 //
0029 // Algorithm:
0030 //
0031 // SIN and COS:
0032 // 1. If SIN is invoked, set AdjN := 0; otherwise, set AdjN := 1.
0033 //
0034 // 2. If |X| >= 15Pi or |X| < 2**(-40), go to 7.
0035 //
0036 // 3. Decompose X as X = N(Pi/2) + r where |r| <= Pi/4. Let
0037 // k = N mod 4, so in particular, k = 0,1,2,or 3. Overwrite
0038 // k by k := k + AdjN.
0039 //
0040 // 4. If k is even, go to 6.
0041 //
0042 // 5. (k is odd) Set j := (k-1)/2, sgn := (-1)**j. Return sgn*cos(r)
0043 // where cos(r) is approximated by an even polynomial in r,
0044 // 1 + r*r*(B1+s*(B2+ ... + s*B8)), s = r*r.
0045 // Exit.
0046 //
0047 // 6. (k is even) Set j := k/2, sgn := (-1)**j. Return sgn*sin(r)
0048 // where sin(r) is approximated by an odd polynomial in r
0049 // r + r*s*(A1+s*(A2+ ... + s*A7)), s = r*r.
0050 // Exit.
0051 //
0052 // 7. If |X| > 1, go to 9.
0053 //
0054 // 8. (|X|<2**(-40)) If SIN is invoked, return X; otherwise return 1.
0055 //
0056 // 9. Overwrite X by X := X rem 2Pi. Now that |X| <= Pi, go back to 3.
0057 //
0058 // SINCOS:
0059 // 1. If |X| >= 15Pi or |X| < 2**(-40), go to 6.
0060 //
0061 // 2. Decompose X as X = N(Pi/2) + r where |r| <= Pi/4. Let
0062 // k = N mod 4, so in particular, k = 0,1,2,or 3.
0063 //
0064 // 3. If k is even, go to 5.
0065 //
0066 // 4. (k is odd) Set j1 := (k-1)/2, j2 := j1 (EOR) (k mod 2), i.e.
0067 // j1 exclusive or with the l.s.b. of k.
0068 // sgn1 := (-1)**j1, sgn2 := (-1)**j2.
0069 // SIN(X) = sgn1 * cos(r) and COS(X) = sgn2*sin(r) where
0070 // sin(r) and cos(r) are computed as odd and even polynomials
0071 // in r, respectively. Exit
0072 //
0073 // 5. (k is even) Set j1 := k/2, sgn1 := (-1)**j1.
0074 // SIN(X) = sgn1 * sin(r) and COS(X) = sgn1*cos(r) where
0075 // sin(r) and cos(r) are computed as odd and even polynomials
0076 // in r, respectively. Exit
0077 //
0078 // 6. If |X| > 1, go to 8.
0079 //
0080 // 7. (|X|<2**(-40)) SIN(X) = X and COS(X) = 1. Exit.
0081 //
0082 // 8. Overwrite X by X := X rem 2Pi. Now that |X| <= Pi, go back to 2.
0083 //
0084
0085 // Copyright (C) Motorola, Inc. 1990
0086 // All Rights Reserved
0087 //
0088 // THIS IS UNPUBLISHED PROPRIETARY SOURCE CODE OF MOTOROLA
0089 // The copyright notice above does not evidence any
0090 // actual or intended publication of such source code.
0091
0092 //SSIN idnt 2,1 | Motorola 040 Floating Point Software Package
0093
0094 |section 8
0095
0096 #include "fpsp.defs"
0097
0098 BOUNDS1: .long 0x3FD78000,0x4004BC7E
0099 TWOBYPI: .long 0x3FE45F30,0x6DC9C883
0100
0101 SINA7: .long 0xBD6AAA77,0xCCC994F5
0102 SINA6: .long 0x3DE61209,0x7AAE8DA1
0103
0104 SINA5: .long 0xBE5AE645,0x2A118AE4
0105 SINA4: .long 0x3EC71DE3,0xA5341531
0106
0107 SINA3: .long 0xBF2A01A0,0x1A018B59,0x00000000,0x00000000
0108
0109 SINA2: .long 0x3FF80000,0x88888888,0x888859AF,0x00000000
0110
0111 SINA1: .long 0xBFFC0000,0xAAAAAAAA,0xAAAAAA99,0x00000000
0112
0113 COSB8: .long 0x3D2AC4D0,0xD6011EE3
0114 COSB7: .long 0xBDA9396F,0x9F45AC19
0115
0116 COSB6: .long 0x3E21EED9,0x0612C972
0117 COSB5: .long 0xBE927E4F,0xB79D9FCF
0118
0119 COSB4: .long 0x3EFA01A0,0x1A01D423,0x00000000,0x00000000
0120
0121 COSB3: .long 0xBFF50000,0xB60B60B6,0x0B61D438,0x00000000
0122
0123 COSB2: .long 0x3FFA0000,0xAAAAAAAA,0xAAAAAB5E
0124 COSB1: .long 0xBF000000
0125
0126 INVTWOPI: .long 0x3FFC0000,0xA2F9836E,0x4E44152A
0127
0128 TWOPI1: .long 0x40010000,0xC90FDAA2,0x00000000,0x00000000
0129 TWOPI2: .long 0x3FDF0000,0x85A308D4,0x00000000,0x00000000
0130
0131 |xref PITBL
0132
0133 .set INARG,FP_SCR4
0134
0135 .set X,FP_SCR5
0136 .set XDCARE,X+2
0137 .set XFRAC,X+4
0138
0139 .set RPRIME,FP_SCR1
0140 .set SPRIME,FP_SCR2
0141
0142 .set POSNEG1,L_SCR1
0143 .set TWOTO63,L_SCR1
0144
0145 .set ENDFLAG,L_SCR2
0146 .set N,L_SCR2
0147
0148 .set ADJN,L_SCR3
0149
0150 | xref t_frcinx
0151 |xref t_extdnrm
0152 |xref sto_cos
0153
0154 .global ssind
0155 ssind:
0156 //--SIN(X) = X FOR DENORMALIZED X
0157 bra t_extdnrm
0158
0159 .global scosd
0160 scosd:
0161 //--COS(X) = 1 FOR DENORMALIZED X
0162
0163 fmoves #0x3F800000,%fp0
0164 //
0165 // 9D25B Fix: Sometimes the previous fmove.s sets fpsr bits
0166 //
0167 fmovel #0,%fpsr
0168 //
0169 bra t_frcinx
0170
0171 .global ssin
0172 ssin:
0173 //--SET ADJN TO 0
0174 movel #0,ADJN(%a6)
0175 bras SINBGN
0176
0177 .global scos
0178 scos:
0179 //--SET ADJN TO 1
0180 movel #1,ADJN(%a6)
0181
0182 SINBGN:
0183 //--SAVE FPCR, FP1. CHECK IF |X| IS TOO SMALL OR LARGE
0184
0185 fmovex (%a0),%fp0 // ...LOAD INPUT
0186
0187 movel (%a0),%d0
0188 movew 4(%a0),%d0
0189 fmovex %fp0,X(%a6)
0190 andil #0x7FFFFFFF,%d0 // ...COMPACTIFY X
0191
0192 cmpil #0x3FD78000,%d0 // ...|X| >= 2**(-40)?
0193 bges SOK1
0194 bra SINSM
0195
0196 SOK1:
0197 cmpil #0x4004BC7E,%d0 // ...|X| < 15 PI?
0198 blts SINMAIN
0199 bra REDUCEX
0200
0201 SINMAIN:
0202 //--THIS IS THE USUAL CASE, |X| <= 15 PI.
0203 //--THE ARGUMENT REDUCTION IS DONE BY TABLE LOOK UP.
0204 fmovex %fp0,%fp1
0205 fmuld TWOBYPI,%fp1 // ...X*2/PI
0206
0207 //--HIDE THE NEXT THREE INSTRUCTIONS
0208 lea PITBL+0x200,%a1 // ...TABLE OF N*PI/2, N = -32,...,32
0209
0210
0211 //--FP1 IS NOW READY
0212 fmovel %fp1,N(%a6) // ...CONVERT TO INTEGER
0213
0214 movel N(%a6),%d0
0215 asll #4,%d0
0216 addal %d0,%a1 // ...A1 IS THE ADDRESS OF N*PIBY2
0217 // ...WHICH IS IN TWO PIECES Y1 & Y2
0218
0219 fsubx (%a1)+,%fp0 // ...X-Y1
0220 //--HIDE THE NEXT ONE
0221 fsubs (%a1),%fp0 // ...FP0 IS R = (X-Y1)-Y2
0222
0223 SINCONT:
0224 //--continuation from REDUCEX
0225
0226 //--GET N+ADJN AND SEE IF SIN(R) OR COS(R) IS NEEDED
0227 movel N(%a6),%d0
0228 addl ADJN(%a6),%d0 // ...SEE IF D0 IS ODD OR EVEN
0229 rorl #1,%d0 // ...D0 WAS ODD IFF D0 IS NEGATIVE
0230 cmpil #0,%d0
0231 blt COSPOLY
0232
0233 SINPOLY:
0234 //--LET J BE THE LEAST SIG. BIT OF D0, LET SGN := (-1)**J.
0235 //--THEN WE RETURN SGN*SIN(R). SGN*SIN(R) IS COMPUTED BY
0236 //--R' + R'*S*(A1 + S(A2 + S(A3 + S(A4 + ... + SA7)))), WHERE
0237 //--R' = SGN*R, S=R*R. THIS CAN BE REWRITTEN AS
0238 //--R' + R'*S*( [A1+T(A3+T(A5+TA7))] + [S(A2+T(A4+TA6))])
0239 //--WHERE T=S*S.
0240 //--NOTE THAT A3 THROUGH A7 ARE STORED IN DOUBLE PRECISION
0241 //--WHILE A1 AND A2 ARE IN DOUBLE-EXTENDED FORMAT.
0242 fmovex %fp0,X(%a6) // ...X IS R
0243 fmulx %fp0,%fp0 // ...FP0 IS S
0244 //---HIDE THE NEXT TWO WHILE WAITING FOR FP0
0245 fmoved SINA7,%fp3
0246 fmoved SINA6,%fp2
0247 //--FP0 IS NOW READY
0248 fmovex %fp0,%fp1
0249 fmulx %fp1,%fp1 // ...FP1 IS T
0250 //--HIDE THE NEXT TWO WHILE WAITING FOR FP1
0251
0252 rorl #1,%d0
0253 andil #0x80000000,%d0
0254 // ...LEAST SIG. BIT OF D0 IN SIGN POSITION
0255 eorl %d0,X(%a6) // ...X IS NOW R'= SGN*R
0256
0257 fmulx %fp1,%fp3 // ...TA7
0258 fmulx %fp1,%fp2 // ...TA6
0259
0260 faddd SINA5,%fp3 // ...A5+TA7
0261 faddd SINA4,%fp2 // ...A4+TA6
0262
0263 fmulx %fp1,%fp3 // ...T(A5+TA7)
0264 fmulx %fp1,%fp2 // ...T(A4+TA6)
0265
0266 faddd SINA3,%fp3 // ...A3+T(A5+TA7)
0267 faddx SINA2,%fp2 // ...A2+T(A4+TA6)
0268
0269 fmulx %fp3,%fp1 // ...T(A3+T(A5+TA7))
0270
0271 fmulx %fp0,%fp2 // ...S(A2+T(A4+TA6))
0272 faddx SINA1,%fp1 // ...A1+T(A3+T(A5+TA7))
0273 fmulx X(%a6),%fp0 // ...R'*S
0274
0275 faddx %fp2,%fp1 // ...[A1+T(A3+T(A5+TA7))]+[S(A2+T(A4+TA6))]
0276 //--FP3 RELEASED, RESTORE NOW AND TAKE SOME ADVANTAGE OF HIDING
0277 //--FP2 RELEASED, RESTORE NOW AND TAKE FULL ADVANTAGE OF HIDING
0278
0279
0280 fmulx %fp1,%fp0 // ...SIN(R')-R'
0281 //--FP1 RELEASED.
0282
0283 fmovel %d1,%FPCR //restore users exceptions
0284 faddx X(%a6),%fp0 //last inst - possible exception set
0285 bra t_frcinx
0286
0287
0288 COSPOLY:
0289 //--LET J BE THE LEAST SIG. BIT OF D0, LET SGN := (-1)**J.
0290 //--THEN WE RETURN SGN*COS(R). SGN*COS(R) IS COMPUTED BY
0291 //--SGN + S'*(B1 + S(B2 + S(B3 + S(B4 + ... + SB8)))), WHERE
0292 //--S=R*R AND S'=SGN*S. THIS CAN BE REWRITTEN AS
0293 //--SGN + S'*([B1+T(B3+T(B5+TB7))] + [S(B2+T(B4+T(B6+TB8)))])
0294 //--WHERE T=S*S.
0295 //--NOTE THAT B4 THROUGH B8 ARE STORED IN DOUBLE PRECISION
0296 //--WHILE B2 AND B3 ARE IN DOUBLE-EXTENDED FORMAT, B1 IS -1/2
0297 //--AND IS THEREFORE STORED AS SINGLE PRECISION.
0298
0299 fmulx %fp0,%fp0 // ...FP0 IS S
0300 //---HIDE THE NEXT TWO WHILE WAITING FOR FP0
0301 fmoved COSB8,%fp2
0302 fmoved COSB7,%fp3
0303 //--FP0 IS NOW READY
0304 fmovex %fp0,%fp1
0305 fmulx %fp1,%fp1 // ...FP1 IS T
0306 //--HIDE THE NEXT TWO WHILE WAITING FOR FP1
0307 fmovex %fp0,X(%a6) // ...X IS S
0308 rorl #1,%d0
0309 andil #0x80000000,%d0
0310 // ...LEAST SIG. BIT OF D0 IN SIGN POSITION
0311
0312 fmulx %fp1,%fp2 // ...TB8
0313 //--HIDE THE NEXT TWO WHILE WAITING FOR THE XU
0314 eorl %d0,X(%a6) // ...X IS NOW S'= SGN*S
0315 andil #0x80000000,%d0
0316
0317 fmulx %fp1,%fp3 // ...TB7
0318 //--HIDE THE NEXT TWO WHILE WAITING FOR THE XU
0319 oril #0x3F800000,%d0 // ...D0 IS SGN IN SINGLE
0320 movel %d0,POSNEG1(%a6)
0321
0322 faddd COSB6,%fp2 // ...B6+TB8
0323 faddd COSB5,%fp3 // ...B5+TB7
0324
0325 fmulx %fp1,%fp2 // ...T(B6+TB8)
0326 fmulx %fp1,%fp3 // ...T(B5+TB7)
0327
0328 faddd COSB4,%fp2 // ...B4+T(B6+TB8)
0329 faddx COSB3,%fp3 // ...B3+T(B5+TB7)
0330
0331 fmulx %fp1,%fp2 // ...T(B4+T(B6+TB8))
0332 fmulx %fp3,%fp1 // ...T(B3+T(B5+TB7))
0333
0334 faddx COSB2,%fp2 // ...B2+T(B4+T(B6+TB8))
0335 fadds COSB1,%fp1 // ...B1+T(B3+T(B5+TB7))
0336
0337 fmulx %fp2,%fp0 // ...S(B2+T(B4+T(B6+TB8)))
0338 //--FP3 RELEASED, RESTORE NOW AND TAKE SOME ADVANTAGE OF HIDING
0339 //--FP2 RELEASED.
0340
0341
0342 faddx %fp1,%fp0
0343 //--FP1 RELEASED
0344
0345 fmulx X(%a6),%fp0
0346
0347 fmovel %d1,%FPCR //restore users exceptions
0348 fadds POSNEG1(%a6),%fp0 //last inst - possible exception set
0349 bra t_frcinx
0350
0351
0352 SINBORS:
0353 //--IF |X| > 15PI, WE USE THE GENERAL ARGUMENT REDUCTION.
0354 //--IF |X| < 2**(-40), RETURN X OR 1.
0355 cmpil #0x3FFF8000,%d0
0356 bgts REDUCEX
0357
0358
0359 SINSM:
0360 movel ADJN(%a6),%d0
0361 cmpil #0,%d0
0362 bgts COSTINY
0363
0364 SINTINY:
0365 movew #0x0000,XDCARE(%a6) // ...JUST IN CASE
0366 fmovel %d1,%FPCR //restore users exceptions
0367 fmovex X(%a6),%fp0 //last inst - possible exception set
0368 bra t_frcinx
0369
0370
0371 COSTINY:
0372 fmoves #0x3F800000,%fp0
0373
0374 fmovel %d1,%FPCR //restore users exceptions
0375 fsubs #0x00800000,%fp0 //last inst - possible exception set
0376 bra t_frcinx
0377
0378
0379 REDUCEX:
0380 //--WHEN REDUCEX IS USED, THE CODE WILL INEVITABLY BE SLOW.
0381 //--THIS REDUCTION METHOD, HOWEVER, IS MUCH FASTER THAN USING
0382 //--THE REMAINDER INSTRUCTION WHICH IS NOW IN SOFTWARE.
0383
0384 fmovemx %fp2-%fp5,-(%a7) // ...save FP2 through FP5
0385 movel %d2,-(%a7)
0386 fmoves #0x00000000,%fp1
0387 //--If compact form of abs(arg) in d0=$7ffeffff, argument is so large that
0388 //--there is a danger of unwanted overflow in first LOOP iteration. In this
0389 //--case, reduce argument by one remainder step to make subsequent reduction
0390 //--safe.
0391 cmpil #0x7ffeffff,%d0 //is argument dangerously large?
0392 bnes LOOP
0393 movel #0x7ffe0000,FP_SCR2(%a6) //yes
0394 // ;create 2**16383*PI/2
0395 movel #0xc90fdaa2,FP_SCR2+4(%a6)
0396 clrl FP_SCR2+8(%a6)
0397 ftstx %fp0 //test sign of argument
0398 movel #0x7fdc0000,FP_SCR3(%a6) //create low half of 2**16383*
0399 // ;PI/2 at FP_SCR3
0400 movel #0x85a308d3,FP_SCR3+4(%a6)
0401 clrl FP_SCR3+8(%a6)
0402 fblt red_neg
0403 orw #0x8000,FP_SCR2(%a6) //positive arg
0404 orw #0x8000,FP_SCR3(%a6)
0405 red_neg:
0406 faddx FP_SCR2(%a6),%fp0 //high part of reduction is exact
0407 fmovex %fp0,%fp1 //save high result in fp1
0408 faddx FP_SCR3(%a6),%fp0 //low part of reduction
0409 fsubx %fp0,%fp1 //determine low component of result
0410 faddx FP_SCR3(%a6),%fp1 //fp0/fp1 are reduced argument.
0411
0412 //--ON ENTRY, FP0 IS X, ON RETURN, FP0 IS X REM PI/2, |X| <= PI/4.
0413 //--integer quotient will be stored in N
0414 //--Intermediate remainder is 66-bit long; (R,r) in (FP0,FP1)
0415
0416 LOOP:
0417 fmovex %fp0,INARG(%a6) // ...+-2**K * F, 1 <= F < 2
0418 movew INARG(%a6),%d0
0419 movel %d0,%a1 // ...save a copy of D0
0420 andil #0x00007FFF,%d0
0421 subil #0x00003FFF,%d0 // ...D0 IS K
0422 cmpil #28,%d0
0423 bles LASTLOOP
0424 CONTLOOP:
0425 subil #27,%d0 // ...D0 IS L := K-27
0426 movel #0,ENDFLAG(%a6)
0427 bras WORK
0428 LASTLOOP:
0429 clrl %d0 // ...D0 IS L := 0
0430 movel #1,ENDFLAG(%a6)
0431
0432 WORK:
0433 //--FIND THE REMAINDER OF (R,r) W.R.T. 2**L * (PI/2). L IS SO CHOSEN
0434 //--THAT INT( X * (2/PI) / 2**(L) ) < 2**29.
0435
0436 //--CREATE 2**(-L) * (2/PI), SIGN(INARG)*2**(63),
0437 //--2**L * (PIby2_1), 2**L * (PIby2_2)
0438
0439 movel #0x00003FFE,%d2 // ...BIASED EXPO OF 2/PI
0440 subl %d0,%d2 // ...BIASED EXPO OF 2**(-L)*(2/PI)
0441
0442 movel #0xA2F9836E,FP_SCR1+4(%a6)
0443 movel #0x4E44152A,FP_SCR1+8(%a6)
0444 movew %d2,FP_SCR1(%a6) // ...FP_SCR1 is 2**(-L)*(2/PI)
0445
0446 fmovex %fp0,%fp2
0447 fmulx FP_SCR1(%a6),%fp2
0448 //--WE MUST NOW FIND INT(FP2). SINCE WE NEED THIS VALUE IN
0449 //--FLOATING POINT FORMAT, THE TWO FMOVE'S FMOVE.L FP <--> N
0450 //--WILL BE TOO INEFFICIENT. THE WAY AROUND IT IS THAT
0451 //--(SIGN(INARG)*2**63 + FP2) - SIGN(INARG)*2**63 WILL GIVE
0452 //--US THE DESIRED VALUE IN FLOATING POINT.
0453
0454 //--HIDE SIX CYCLES OF INSTRUCTION
0455 movel %a1,%d2
0456 swap %d2
0457 andil #0x80000000,%d2
0458 oril #0x5F000000,%d2 // ...D2 IS SIGN(INARG)*2**63 IN SGL
0459 movel %d2,TWOTO63(%a6)
0460
0461 movel %d0,%d2
0462 addil #0x00003FFF,%d2 // ...BIASED EXPO OF 2**L * (PI/2)
0463
0464 //--FP2 IS READY
0465 fadds TWOTO63(%a6),%fp2 // ...THE FRACTIONAL PART OF FP1 IS ROUNDED
0466
0467 //--HIDE 4 CYCLES OF INSTRUCTION; creating 2**(L)*Piby2_1 and 2**(L)*Piby2_2
0468 movew %d2,FP_SCR2(%a6)
0469 clrw FP_SCR2+2(%a6)
0470 movel #0xC90FDAA2,FP_SCR2+4(%a6)
0471 clrl FP_SCR2+8(%a6) // ...FP_SCR2 is 2**(L) * Piby2_1
0472
0473 //--FP2 IS READY
0474 fsubs TWOTO63(%a6),%fp2 // ...FP2 is N
0475
0476 addil #0x00003FDD,%d0
0477 movew %d0,FP_SCR3(%a6)
0478 clrw FP_SCR3+2(%a6)
0479 movel #0x85A308D3,FP_SCR3+4(%a6)
0480 clrl FP_SCR3+8(%a6) // ...FP_SCR3 is 2**(L) * Piby2_2
0481
0482 movel ENDFLAG(%a6),%d0
0483
0484 //--We are now ready to perform (R+r) - N*P1 - N*P2, P1 = 2**(L) * Piby2_1 and
0485 //--P2 = 2**(L) * Piby2_2
0486 fmovex %fp2,%fp4
0487 fmulx FP_SCR2(%a6),%fp4 // ...W = N*P1
0488 fmovex %fp2,%fp5
0489 fmulx FP_SCR3(%a6),%fp5 // ...w = N*P2
0490 fmovex %fp4,%fp3
0491 //--we want P+p = W+w but |p| <= half ulp of P
0492 //--Then, we need to compute A := R-P and a := r-p
0493 faddx %fp5,%fp3 // ...FP3 is P
0494 fsubx %fp3,%fp4 // ...W-P
0495
0496 fsubx %fp3,%fp0 // ...FP0 is A := R - P
0497 faddx %fp5,%fp4 // ...FP4 is p = (W-P)+w
0498
0499 fmovex %fp0,%fp3 // ...FP3 A
0500 fsubx %fp4,%fp1 // ...FP1 is a := r - p
0501
0502 //--Now we need to normalize (A,a) to "new (R,r)" where R+r = A+a but
0503 //--|r| <= half ulp of R.
0504 faddx %fp1,%fp0 // ...FP0 is R := A+a
0505 //--No need to calculate r if this is the last loop
0506 cmpil #0,%d0
0507 bgt RESTORE
0508
0509 //--Need to calculate r
0510 fsubx %fp0,%fp3 // ...A-R
0511 faddx %fp3,%fp1 // ...FP1 is r := (A-R)+a
0512 bra LOOP
0513
0514 RESTORE:
0515 fmovel %fp2,N(%a6)
0516 movel (%a7)+,%d2
0517 fmovemx (%a7)+,%fp2-%fp5
0518
0519
0520 movel ADJN(%a6),%d0
0521 cmpil #4,%d0
0522
0523 blt SINCONT
0524 bras SCCONT
0525
0526 .global ssincosd
0527 ssincosd:
0528 //--SIN AND COS OF X FOR DENORMALIZED X
0529
0530 fmoves #0x3F800000,%fp1
0531 bsr sto_cos //store cosine result
0532 bra t_extdnrm
0533
0534 .global ssincos
0535 ssincos:
0536 //--SET ADJN TO 4
0537 movel #4,ADJN(%a6)
0538
0539 fmovex (%a0),%fp0 // ...LOAD INPUT
0540
0541 movel (%a0),%d0
0542 movew 4(%a0),%d0
0543 fmovex %fp0,X(%a6)
0544 andil #0x7FFFFFFF,%d0 // ...COMPACTIFY X
0545
0546 cmpil #0x3FD78000,%d0 // ...|X| >= 2**(-40)?
0547 bges SCOK1
0548 bra SCSM
0549
0550 SCOK1:
0551 cmpil #0x4004BC7E,%d0 // ...|X| < 15 PI?
0552 blts SCMAIN
0553 bra REDUCEX
0554
0555
0556 SCMAIN:
0557 //--THIS IS THE USUAL CASE, |X| <= 15 PI.
0558 //--THE ARGUMENT REDUCTION IS DONE BY TABLE LOOK UP.
0559 fmovex %fp0,%fp1
0560 fmuld TWOBYPI,%fp1 // ...X*2/PI
0561
0562 //--HIDE THE NEXT THREE INSTRUCTIONS
0563 lea PITBL+0x200,%a1 // ...TABLE OF N*PI/2, N = -32,...,32
0564
0565
0566 //--FP1 IS NOW READY
0567 fmovel %fp1,N(%a6) // ...CONVERT TO INTEGER
0568
0569 movel N(%a6),%d0
0570 asll #4,%d0
0571 addal %d0,%a1 // ...ADDRESS OF N*PIBY2, IN Y1, Y2
0572
0573 fsubx (%a1)+,%fp0 // ...X-Y1
0574 fsubs (%a1),%fp0 // ...FP0 IS R = (X-Y1)-Y2
0575
0576 SCCONT:
0577 //--continuation point from REDUCEX
0578
0579 //--HIDE THE NEXT TWO
0580 movel N(%a6),%d0
0581 rorl #1,%d0
0582
0583 cmpil #0,%d0 // ...D0 < 0 IFF N IS ODD
0584 bge NEVEN
0585
0586 NODD:
0587 //--REGISTERS SAVED SO FAR: D0, A0, FP2.
0588
0589 fmovex %fp0,RPRIME(%a6)
0590 fmulx %fp0,%fp0 // ...FP0 IS S = R*R
0591 fmoved SINA7,%fp1 // ...A7
0592 fmoved COSB8,%fp2 // ...B8
0593 fmulx %fp0,%fp1 // ...SA7
0594 movel %d2,-(%a7)
0595 movel %d0,%d2
0596 fmulx %fp0,%fp2 // ...SB8
0597 rorl #1,%d2
0598 andil #0x80000000,%d2
0599
0600 faddd SINA6,%fp1 // ...A6+SA7
0601 eorl %d0,%d2
0602 andil #0x80000000,%d2
0603 faddd COSB7,%fp2 // ...B7+SB8
0604
0605 fmulx %fp0,%fp1 // ...S(A6+SA7)
0606 eorl %d2,RPRIME(%a6)
0607 movel (%a7)+,%d2
0608 fmulx %fp0,%fp2 // ...S(B7+SB8)
0609 rorl #1,%d0
0610 andil #0x80000000,%d0
0611
0612 faddd SINA5,%fp1 // ...A5+S(A6+SA7)
0613 movel #0x3F800000,POSNEG1(%a6)
0614 eorl %d0,POSNEG1(%a6)
0615 faddd COSB6,%fp2 // ...B6+S(B7+SB8)
0616
0617 fmulx %fp0,%fp1 // ...S(A5+S(A6+SA7))
0618 fmulx %fp0,%fp2 // ...S(B6+S(B7+SB8))
0619 fmovex %fp0,SPRIME(%a6)
0620
0621 faddd SINA4,%fp1 // ...A4+S(A5+S(A6+SA7))
0622 eorl %d0,SPRIME(%a6)
0623 faddd COSB5,%fp2 // ...B5+S(B6+S(B7+SB8))
0624
0625 fmulx %fp0,%fp1 // ...S(A4+...)
0626 fmulx %fp0,%fp2 // ...S(B5+...)
0627
0628 faddd SINA3,%fp1 // ...A3+S(A4+...)
0629 faddd COSB4,%fp2 // ...B4+S(B5+...)
0630
0631 fmulx %fp0,%fp1 // ...S(A3+...)
0632 fmulx %fp0,%fp2 // ...S(B4+...)
0633
0634 faddx SINA2,%fp1 // ...A2+S(A3+...)
0635 faddx COSB3,%fp2 // ...B3+S(B4+...)
0636
0637 fmulx %fp0,%fp1 // ...S(A2+...)
0638 fmulx %fp0,%fp2 // ...S(B3+...)
0639
0640 faddx SINA1,%fp1 // ...A1+S(A2+...)
0641 faddx COSB2,%fp2 // ...B2+S(B3+...)
0642
0643 fmulx %fp0,%fp1 // ...S(A1+...)
0644 fmulx %fp2,%fp0 // ...S(B2+...)
0645
0646
0647
0648 fmulx RPRIME(%a6),%fp1 // ...R'S(A1+...)
0649 fadds COSB1,%fp0 // ...B1+S(B2...)
0650 fmulx SPRIME(%a6),%fp0 // ...S'(B1+S(B2+...))
0651
0652 movel %d1,-(%sp) //restore users mode & precision
0653 andil #0xff,%d1 //mask off all exceptions
0654 fmovel %d1,%FPCR
0655 faddx RPRIME(%a6),%fp1 // ...COS(X)
0656 bsr sto_cos //store cosine result
0657 fmovel (%sp)+,%FPCR //restore users exceptions
0658 fadds POSNEG1(%a6),%fp0 // ...SIN(X)
0659
0660 bra t_frcinx
0661
0662
0663 NEVEN:
0664 //--REGISTERS SAVED SO FAR: FP2.
0665
0666 fmovex %fp0,RPRIME(%a6)
0667 fmulx %fp0,%fp0 // ...FP0 IS S = R*R
0668 fmoved COSB8,%fp1 // ...B8
0669 fmoved SINA7,%fp2 // ...A7
0670 fmulx %fp0,%fp1 // ...SB8
0671 fmovex %fp0,SPRIME(%a6)
0672 fmulx %fp0,%fp2 // ...SA7
0673 rorl #1,%d0
0674 andil #0x80000000,%d0
0675 faddd COSB7,%fp1 // ...B7+SB8
0676 faddd SINA6,%fp2 // ...A6+SA7
0677 eorl %d0,RPRIME(%a6)
0678 eorl %d0,SPRIME(%a6)
0679 fmulx %fp0,%fp1 // ...S(B7+SB8)
0680 oril #0x3F800000,%d0
0681 movel %d0,POSNEG1(%a6)
0682 fmulx %fp0,%fp2 // ...S(A6+SA7)
0683
0684 faddd COSB6,%fp1 // ...B6+S(B7+SB8)
0685 faddd SINA5,%fp2 // ...A5+S(A6+SA7)
0686
0687 fmulx %fp0,%fp1 // ...S(B6+S(B7+SB8))
0688 fmulx %fp0,%fp2 // ...S(A5+S(A6+SA7))
0689
0690 faddd COSB5,%fp1 // ...B5+S(B6+S(B7+SB8))
0691 faddd SINA4,%fp2 // ...A4+S(A5+S(A6+SA7))
0692
0693 fmulx %fp0,%fp1 // ...S(B5+...)
0694 fmulx %fp0,%fp2 // ...S(A4+...)
0695
0696 faddd COSB4,%fp1 // ...B4+S(B5+...)
0697 faddd SINA3,%fp2 // ...A3+S(A4+...)
0698
0699 fmulx %fp0,%fp1 // ...S(B4+...)
0700 fmulx %fp0,%fp2 // ...S(A3+...)
0701
0702 faddx COSB3,%fp1 // ...B3+S(B4+...)
0703 faddx SINA2,%fp2 // ...A2+S(A3+...)
0704
0705 fmulx %fp0,%fp1 // ...S(B3+...)
0706 fmulx %fp0,%fp2 // ...S(A2+...)
0707
0708 faddx COSB2,%fp1 // ...B2+S(B3+...)
0709 faddx SINA1,%fp2 // ...A1+S(A2+...)
0710
0711 fmulx %fp0,%fp1 // ...S(B2+...)
0712 fmulx %fp2,%fp0 // ...s(a1+...)
0713
0714
0715
0716 fadds COSB1,%fp1 // ...B1+S(B2...)
0717 fmulx RPRIME(%a6),%fp0 // ...R'S(A1+...)
0718 fmulx SPRIME(%a6),%fp1 // ...S'(B1+S(B2+...))
0719
0720 movel %d1,-(%sp) //save users mode & precision
0721 andil #0xff,%d1 //mask off all exceptions
0722 fmovel %d1,%FPCR
0723 fadds POSNEG1(%a6),%fp1 // ...COS(X)
0724 bsr sto_cos //store cosine result
0725 fmovel (%sp)+,%FPCR //restore users exceptions
0726 faddx RPRIME(%a6),%fp0 // ...SIN(X)
0727
0728 bra t_frcinx
0729
0730 SCBORS:
0731 cmpil #0x3FFF8000,%d0
0732 bgt REDUCEX
0733
0734
0735 SCSM:
0736 movew #0x0000,XDCARE(%a6)
0737 fmoves #0x3F800000,%fp1
0738
0739 movel %d1,-(%sp) //save users mode & precision
0740 andil #0xff,%d1 //mask off all exceptions
0741 fmovel %d1,%FPCR
0742 fsubs #0x00800000,%fp1
0743 bsr sto_cos //store cosine result
0744 fmovel (%sp)+,%FPCR //restore users exceptions
0745 fmovex X(%a6),%fp0
0746 bra t_frcinx
0747
0748 |end
